EXEL VBA Kommentare

Re(6): EXEL VBA Kommentare

Codename 47 — Fri, 30 Jan 2004 11:46:00 GMT

aso ein kollega, zum teil zumindest

bin nämlich echt überrascht, dass du mir helfen kannst.. alle programmierer die ich so kenne haben keine ahnung (mehr) von vba...

wobei vom prinzip is es ja dotnet sehr ähnlich, was ja stark im kommen ist...

Re(5): EXEL VBA Kommentare

hariw — Fri, 30 Jan 2004 09:17:50 GMT

hi,

je nach dem, entw. student oder selbstst. gewerbetreibender (wie´s halt grad vorteilhafter ist )
anfangs office schulungen, mittlerweile ausschließlich support...

lg,
hariw

Re(4): EXEL VBA Kommentare

Codename 47 — Fri, 30 Jan 2004 07:30:05 GMT

bist du gescheit... ist doch a bissal komplizierter als ich gedacht habe....

Vielen DANK!!!

sag was machst du schulisch/beruflich????

oder sollte das allgemeinbildung sein???

Re(2): EXEL VBA Kommentare

TheTrumpeter — Thu, 29 Jan 2004 23:24:57 GMT

Das ist auch meine Methode... geht ganz gut so... zuerst anschauen, dann den überflüssigen Mist raushauen oder nur bestimmte Teile übernehmen...

Re(3): EXEL VBA Kommentare

hariw — Thu, 29 Jan 2004 23:13:23 GMT

hi,

anm: als zusatzaufgabe darfst noch den übergebenen range "target" abfragen und prüfen, ob er im zielbereich liegt und wenn, dann myrange auf "target" verweisen und das makro somit nur auf die "veränderte zelle" ausführen...
im monmet is ein bissl inperformant...

lg,
hariw

Re(3): EXEL VBA Kommentare

hariw — Thu, 29 Jan 2004 23:02:49 GMT

hi,

soda, folgenden code in DieseArbeitsmappe einfügen...
makro läuft zwar bei jeder eingabe an der kompletten mappe, änderungen "greifen" aber nur im range A1:G30...(aber an jedem sheet!, müsstest bei set myrange statt activesheet das sheet mit bezeichnung anführen)

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
    Dim myCell As Range
    Dim myRange As Range

    Set myRange = ActiveWorkbook.ActiveSheet.Range("A1", "G30")

    For Each myCell In myRange
        If GetCellColor(myCell) = 3 Then
            If Not myCell.Comment Is Nothing Then myCell.ClearComments
            myCell.AddComment "Dein Kommentar"
        Else: myCell.ClearComments
        End If
    Next

End Sub

Function GetCellColor(cell As Range) As Integer
    Dim i
    Dim myVal
    Dim myColor As Integer
    Dim done As Boolean
    On Error Resume Next
    Names("testRange").Delete
    On Error GoTo 0
    Application.ReferenceStyle = xlR1C1
    myVal = cell.Value
    myColor = cell.Interior.ColorIndex
    done = False
    For i = 1 To cell.FormatConditions.Count
        With cell.FormatConditions.Item(i)
            If .Type = 1 Then
                Select Case .Operator
                    Case xlBetween
                        If (myVal >= Evaluate(.Formula1) And myVal <= Evaluate(.Formula2)) _
                            Or (myVal <= Evaluate(.Formula1) And myVal >= Evaluate(.Formula2)) Then
                            myColor = .Interior.ColorIndex
                            done = True
                        End If
                    Case xlEqual
                        If myVal = Evaluate(.Formula1) Then
                            myColor = .Interior.ColorIndex
                            done = True
                        End If
                    Case xlGreater
                        If myVal > Evaluate(.Formula1) Then
                            myColor = .Interior.ColorIndex
                            done = True
                        End If
                    Case xlGreaterEqual
                        If myVal >= Evaluate(.Formula1) Then
                            myColor = .Interior.ColorIndex
                            done = True
                        End If
                    Case xlLess
                        If myVal < Evaluate(.Formula1) Then
                            myColor = .Interior.ColorIndex
                            done = True
                        End If
                    Case xlLessEqual
                        If myVal <= Evaluate(.Formula1) Then
                            myColor = .Interior.ColorIndex
                            done = True
                        End If
                    Case xlNotBetween
                        If myVal < Evaluate(.Formula1) Or myVal > Evaluate(.Formula2) Then
                            myColor = .Interior.ColorIndex
                            done = True
                        End If
                    Case xlNotEqual
                        If myVal <> Evaluate(.Formula1) Then
                            myColor = .Interior.ColorIndex
                            done = True
                        End If
                End Select
            ElseIf .Type = 2 Then
                Names.Add Name:="testRange", RefersToR1C1Local:=.Formula1
                If Evaluate("testRange") Then
                    myColor = .Interior.ColorIndex
                    done = True
                End If
                Names("testRange").Delete
            Else
                MsgBox "Unbekannter Typ: " & .Type
                Exit Function
            End If
        End With
        If done Then Exit For
    Next
    Application.ReferenceStyle = xlA1
    GetCellColor = myColor
End Function

lg,
hariw

ps: stiegl schmeckt mir recht gut

Re(3): EXEL VBA Kommentare

hariw — Thu, 29 Jan 2004 22:50:49 GMT

hi,

> ich glaube dass es nicht alzu schwer sein sollte...

wie man sich täuschen kann

> weisst du woran das liegen könnte????

die farbe ist nicht eindeutig einer zelle zugeordnet und kann daher nicht als property ausgelesen werden...

> mir is klar das das programm ned voll variabel sein kann

sollt´s das sein?

sollt auch noch machbar sein

gib mir noch 5 min...

im nächsten posting folgt der code...

lg,
hariw

Re(2): EXEL VBA Kommentare

Codename 47 — Thu, 29 Jan 2004 09:32:00 GMT

http://forum.geizhals.at/t224990,1287852.html#1287852

Re(2): EXEL VBA Kommentare

Codename 47 — Thu, 29 Jan 2004 08:18:56 GMT

leider nein

hatte es selbst ähnlich versucht aber es funkt leida ned richtig

wenn ich ein feld einfach rot mache dann geht es...

aber ich habe felder die durch "bedingte formatierung" in bestimmten fällen (zahl größer als x) rot werden. und dort funkt das seltsamerweise ned.. ????

weisst du woran das liegen könnte???? danke im *TRÖT*.

mfg codename

PS: mir is klar das das programm ned voll variabel sein kann und bei jeder änderung der zahl im feld comments nachjustieren kann.

Aber ich hab ne delete funktion für nicht rote felder hinzugefügt
( Else: myCell.ClearComments) und einen button aufs sheet gegeben der den sub ausführt. Es reicht mir wenn er die comments nur beim drücken des button aktualisiert.

Re(2): EXEL VBA Kommentare

Codename 47 — Thu, 29 Jan 2004 00:14:29 GMT

DANKE!!!!!

Re(2): EXEL VBA Kommentare

Codename 47 — Thu, 29 Jan 2004 00:14:04 GMT

werds gleich probieren! vielen DANK!!!

Re: EXEL VBA Kommentare

Xane — Wed, 28 Jan 2004 18:32:23 GMT

Ich mach das immer so:
1. Makro aufnehmen, das nach Dingen sucht
2. Makro aufnehmen, das einen Kommentar schreibt.

Dann die Makros studieren, schauen welche Objekte, Eigenschaften und Methoden benutzt werden und das End Makro zusammenbasteln ...

das von hariw sieht eigentlich schon ganz ordentlich aus ...

Re: EXEL VBA Kommentare

hariw — Wed, 28 Jan 2004 18:26:33 GMT

hi,

gut, ich gib dir einen tip

Sub addComments()
    Dim myCell As Range
    Dim myRange As Range

    Set myRange = ActiveWorkbook.ActiveSheet.Range("A1", "G30")

    For Each myCell In myRange
        If myCell.Interior.Color = 255 Then
            If Not myCell.Comment Is Nothing Then myCell.ClearComments
            myCell.AddComment "dein Kommentar"
        End If
    Next
End Sub

lg,
hariw

Re: EXEL VBA Kommentare

littleo — Wed, 28 Jan 2004 16:43:45 GMT

Sub scansForRedBackgrounds()

Dim currentCell, rngWoGucken As Range

Set rngWoGucken = Range("A1", "A25")

For i = 1 To rngWoGucken.Rows.Count
Set currentCell = rngWoGucken.Cells(i, 1)
If (currentCell.Interior.Color = 255) Then MsgBox ("juhu gefunden in reihe " & _
currentCell.Row & " column " & currentCell.Column)

Next
End Sub

EXEL VBA Kommentare

Codename 47 — Wed, 28 Jan 2004 16:03:38 GMT

Hallo!

Ich hab ein Excel sheet in dem zellen grün oder rot eingefärbt sind je nachdem ob die werte über unter unter einem richtwert liegen.

Jetzt würde ich gerne ein kleines vba prog schreiben, dass bei den Zellen mit rotem Hintergrund ein Kommentar einfügt.

krieg das leider ned zam bräuchte es so das es einen bestimmten rahmen z.b.(a11:c22) nach roten feldern scannt und gegebenfalls ein kommentar hinzufügt...

hat zufällig jemand sowas?? bzw ich glaube dass es nicht alzu schwer sein sollte könnte mir jemand ein zwei tipps geben???

danke!!!

mfg codename