Netzwerküberwachungs Tool

Re: Netzwerküberwachungs Tool

Glockman — Tue, 28 Sep 2010 16:12:10 GMT

Hi!

Ich hab mir damals sowas selbst geschrieben, allerdings für einen anderen Zweck... müsste aber auch in dem Fall helfen.


strComputer = "."
strPingTarget = "xxx.xxx.xxx.xxx"
strOutFile = "C:\ping_error.log"
intNormalInterval = 5000
intFailureInterval = 1000

Set fso = CreateObject("Scripting.FileSystemObject")

Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set Logfile = fso.OpenTextFile(strOutFile, 8, True, 0)
Logfile.Writeline "**********************************************************************"
Logfile.WriteLine "Ping check startup at " & time & " on " & date & " with ping target= " & strPingTarget & " , ping interval= " & intNormalInterval / 1000 & " sec"
Logfile.Close
Set Logfile = Nothing

Interval = intNormalInterval

Do
Set Logfile = fso.OpenTextFile(strOutFile, 8, True, 0)
Set colPings = objWMIService.ExecQuery ("Select * From Win32_PingStatus where Address = '" & strPingTarget & "'")
    For Each objStatus in colPings
        If IsNull(objStatus.StatusCode) _
            or objStatus.StatusCode<>0 Then
            Interval = intFailureInterval
            Logfile.WriteLine "Computer " & strPingTarget & " did not respond at " & time & " on " & date & ", setting ping interval to " & intFailureInterval / 1000 & " sec"
        Else
            If Interval = intFailureInterval Then
              Interval = intNormalInterval
              Logfile.WriteLine "Computer " & strPingTarget & " responded at " & time & " on " & date & ", resetting ping interval to " & intNormalInterval / 1000 & " sec"
            End If
        End If
    Next
    Logfile.Close
    WScript.Sleep Interval
Loop

Bei strPingTarget die Ziel-IP eingeben, die Zahlenwerte für Normal/Fehler sind Millisekunden. Ins Log kommt dann die Info über geht/geht nicht samt Zeit-/Datumsangabe.
Beenden über Prozessabschuss (w/cscript.exe).

hth,

Re: Netzwerküberwachungs Tool

MrT2004 — Tue, 28 Sep 2010 15:45:48 GMT

wireshark

Re: Netzwerküberwachungs Tool

na ich halt — Tue, 28 Sep 2010 12:17:16 GMT

Oder einfach ein Batchfile mit folgendem Inhalt:

Ping 192.168.1.2 -t >>ping.LOG

Ist die einfachste Möglichkeit, aber leider ohne Zeitangabe...

Abzubrechen nur mit Ctrl + Taste "c"

Die Datei dafr natürlich nicht Ping.bat heißen

Re: Netzwerküberwachungs Tool

Desolationrob — Tue, 28 Sep 2010 11:54:32 GMT

türlich, pingplotter, da sollte die eval reichen, ansonsten gibts von colasoft was, etc. Solltest aber a. verraten um welches OS es geht und b erwägen das die Probleme nicht alle nur mit simplen ping tests diagnostiziert werden können. Da muss man sich schon den ganzen Weg bis zu Ziel anschauen.

Netzwerküberwachungs Tool

werni007 — Tue, 28 Sep 2010 10:43:12 GMT

Habe gerade von einem Problem eines Benutzers gehört der hin und wieder Netzwerkausfälle auf seinem rechner hat - ist aber nur der eine user - deshalb liegt die vermutung nahe dass er der rechner des users ist!

ich suche jetzt ein tool um quasi den netzwerkverkehr zu überwachen - der benutzer ist momentan auf urlaub daher ist der zugriff auf den rechner uneingeschränkt möglich!

was ich mir gedacht habe:
ein tool laufen zu lassen dass einen server im netz alle ~3sek pingt und das ganze in ein log file schreibt!
super wäre auch noch wieviele pakete verloren wurden und die uhrzeit!

gibts so ein tool?