' Check for status of a service and terminate a given executable if service state changed
' 
' Parameters:
' ServiceName - name of the service as seen under "Service name" when looking at the service's properties
' ExecName    - name of the executable to be terminated if service state changed
' Interval    - time in seconds to wait for next status check
' strComputer - machine to run the query on; specify "." if the local machine is being used

Option Explicit

Call CheckService("messenger", "calc.exe", 1)

Sub CheckService(ServiceName, ExecName, Interval)

Dim strComputer
Dim objWMI, objWMIQrySrv, objWMIQryExe, objWMIQryResultSrv, objWMIQryResultExe

strComputer = "."

Set objWMI = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Do
  Set objWMIQrySrv = objWMI.ExecQuery("Select * from Win32_Service where Name = '" & ServiceName & "'")
  For Each objWMIQryResultSrv in objWMIQrySrv
      If objWMIQryResultSrv.State = "Stop Pending" Then
         Set objWMIQryExe = objWMI.ExecQuery("Select * from Win32_Process where Name = '" & ExecName & "'")
         For Each objWMIQryResultExe in objWMIQryExe
             objWMIQryResultExe.Terminate (0)
         Next
      End If
  Next
  Set objWMIQrySrv = Nothing
  Set objWMIQryResultSrv = Nothing
  Set objWMIQryExe = Nothing
  Set objWMIQryResultExe = Nothing
  WScript.Sleep Interval * 1000
Loop

End Sub