Excel Problem

Excel Problem (10 Beiträge, 269 Mal gelesen)

Du bist nicht angemeldet. [ Login/Registrieren ]

Hi;

ich hab mit der Programmierung von Excel 0 Ahnung sollte dennoch ev. ein kleines Problem lösen - und zwar hab ich ein Excel Sheet welches in einer Spalte lauter Gruppen aus den Elementen 1,2 oder 3 hat (jede Zeile ist eine Sekunde)... es sieht etwas so aus:

1
1
2
2
2
1
1
3
3
3
3
3
1
1
1
usw...

Wie bekomme ich nun
* eine Spalte in der ich Anzahl des Auftretens zusammenfasse? Im obigen Fall zb..
2 x 1 (2 mal kommt die 1)
3 x 2 (3 mal kommt die 2)...
2 x 1
...

*und wie komme ich zur durchschnittlichen Gruppengröße? In obigen Fall zb für "1" kommt 7x in 3 Gruppen vor -> durchschnittliche Gruppengröße 7/3=2,333

thks
fz

Wie bekomme ich nun
* eine Spalte in der ich Anzahl des Auftretens zusammenfasse?

willst du nur wissen, "wie oft" ?
Dann mit "COUNTIF"

wie komme ich zur durchschnittlichen Gruppengröße? In obigen Fall zb für "1"
kommt 7x in 3 Gruppen vor -> durchschnittliche Gruppengröße 7/3=2,333

die Frage versteh ich nicht.
Was willst du jetzt genau?

mfg
AVS

Naja - ich hab eine Spalte mit lauter Folgen von Elementen 1,2 oder 3 - 11122322111133322211
Ich will nun wissen, aus wie vielen Elementen so diese Gruppen so bestehen - für die "1" zb zuerst 3x dann kommt die "1" 4x hintereinander und dann noch einmal 2x hintereinander vor - das macht also 3 x 1er Gruppen bei insgesamt 3+4+2=9 Elementen -> 9 (Elemente) / 3 (Vorkommen) = 3 (durchschnittlich besteht so eine Gruppe aus 3 Elementen)...

eine Spalte mit lauter Folgen von Elementen 1,2 oder 3 - 11122322111133322211

ich dachte, in einer Zelle steht immer nur eine Zahl?
wenn da 11122322111133322211 in einer Zelle steht, dann geht da mit COUNTIF natürlich nix mehr.
Und Zeichenfolgen erkennen mit Excel?? Da fällt mir nix mehr dazu ein.

mfg
AVS

ich les mich jetzt in VBA ein und bau mir selber ein makro...

Ich würd jetzt eine ganz "primitive" Lösung vorschlagen

in meinem Beispiel steht der erste 1er in Zelle A3, eine Leerzeile drüber sollte sein, das ganze mal am Beispiel "1":

Zuerst machst du dir eine Spalte mit WENN Abfragen z.B. =WENN(A3=1;1;"") , die auf bei Auftreten von 1 in der ersten Spalte einfach einen 1er setzen, und dann eine Spalte, die ebenfalls mit einer WENN Abfrage den Wert 1 annimmt, sobald in der aktuellen Zeile eine 1 steht =WENN(UND(B3=1;B2="");1;"") , und in der vorhergehenden Zelle Nichts > diese 1er summierst du dann =SUMME(C3:C17), und hast somit ohne VBA und stundenlanges Herumdoktern in nicht mal 10 Minuten das erste Problem gelöst > 3 Gruppen mit 1ern.

Die Gruppengröße wird etwas schwieriger, aber ausgehend von der zuvor erstellten Reihe, baut man aus eine Reihe mit 1ern, einfache eine Dritte =WENN(B3=1; D4+1;0), logisch jetzt etwas verkehrt, weil es von unten nach oben zählt, aber das ist wegen meiner zweiten Reihe, weil ich diese jetzt mit =WENN(C3=1;D3;"") dazu benutze, die Summe der einzelnen Gruppen in eine 4e Reihe zu schreiben > diese dann wieder summieren, und durch die Gruppenanzahl =SUMME(E3:E17)/C18 > Mittelwert 2,3333

Aber das ist jetzt nur mal ein Denkansatz.

15.02.2013, 17:59 Uhr - Editiert von to_markus, alte Version: hier

Hi,
ich hab dir mal kurz (quick & dirty) ein Makro zusammen geschrieben:

############################################

Option Explicit

Private Sub countGroups()
Dim iRow As Integer
Dim iLastRow As Integer
Dim iOutputRowGroupCount As Integer
Dim iOutputRowsDistinctValues As Integer
Dim iCurrentRowDistinctValues As Integer
Dim iGroupCounter As Integer
Dim iArrayCounter As Integer

Dim sCurrentValue As String
Dim sPreviousValue As String

Dim bValueFound As Boolean

    iOutputRowGroupCount = 1
    iLastRow = UsedRange.SpecialCells(xlCellTypeLastCell).Row

    For iRow = 1 To iLastRow + 1
        sCurrentValue = Cells(iRow, 1).Value

        If sCurrentValue = sPreviousValue Then
            iGroupCounter = iGroupCounter + 1
        Else
            If iRow > 1 Then
                Cells(iOutputRowGroupCount, 2).Value = iGroupCounter & " x " & sPreviousValue
                iOutputRowGroupCount = iOutputRowGroupCount + 1

                bValueFound = False
                For iCurrentRowDistinctValues = 1 To iOutputRowsDistinctValues
                    If Cells(iCurrentRowDistinctValues, 3).Value = sPreviousValue Then
                        Cells(iCurrentRowDistinctValues, 4).Value = Cells(iCurrentRowDistinctValues, 4).Value + 1
                        Cells(iCurrentRowDistinctValues, 5).Value = Cells(iCurrentRowDistinctValues, 5).Value + iGroupCounter
                        bValueFound = True
                    End If
                Next iCurrentRowDistinctValues

                If Not bValueFound Then
                    iOutputRowsDistinctValues = iOutputRowsDistinctValues + 1
                    Cells(iOutputRowsDistinctValues, 3).Value = sPreviousValue
                    Cells(iOutputRowsDistinctValues, 4).Value = 1
                    Cells(iOutputRowsDistinctValues, 5).Value = iGroupCounter
                End If
            End If
            iGroupCounter = 1
        End If

        sPreviousValue = sCurrentValue
    Next iRow

    For iCurrentRowDistinctValues = 1 To iOutputRowsDistinctValues
        Cells(iCurrentRowDistinctValues, 6).Value = Cells(iCurrentRowDistinctValues, 5).Value / Cells(iCurrentRowDistinctValues, 4).Value
    Next iCurrentRowDistinctValues
End Sub

############################################

In Spalte A müssen die Werte stehen, Ausgabe erfolgt in der folgenden Reihenfolge:
Spalte B: Vorkommen pro Gruppe (2 x 1, 3 x 2, ...)
Spalten C - E sind eigentlich nur der Einfachheit halber ausgegeben. Spalte C: Wert, Spalte D: Anzahl der Gruppen, Spalte E: Vorkommen gesamt
Spalte D: durchschnittliche Gruppengröße (berechnet sich aus Spalte D durch Spalte E, Wert steht in Spalte C)

Das ganze kommt wahrscheinlich ein wenig konfus rüber, aber ich habs grade schon sehr eilig. Falls du noch Fragen oder Wünsche hast, schreib einfach. Ich schau am Nachmittag wieder rein.

Grüße
Karli

16.02.2013, 13:14 Uhr - Editiert von KarliKarli, alte Version: hier

ohne Makros:
https://forum.geizhals.at/files/73840/123.xlsx

Dieses Forum ist eine frei zugängliche Diskussionsplattform.
Der Betreiber übernimmt keine Verantwortung für den Inhalt der Beiträge und behält sich das Recht vor, Beiträge mit rechtswidrigem oder anstößigem Inhalt zu löschen.
Datenschutzerklärung