Option Explicit

If WScript.Arguments.Count = 2 Then
   Call DeleteOldfiles(WScript.Arguments(0), WScript.Arguments(1))
Else
   WScript.Echo "Usage: " & WScript.ScriptName & " <Pfad> <Dateien_älter_als_X_Tage>" & vbCrLf & vbCrLf & _
                 "Wenn <Pfad> Leerzeichen enthält, unter Anführungszeichen setzen."
End If

Sub DeleteOldFiles(Path, Interval)

    Dim FCount, strFile, dtmFileDate, dtmOldestDate
    Dim objFSO, objFolder, colFiles, objFile

    dtmOldestDate = DateAdd("d", -Interval, Now)

    Set objFSO = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFSO.GetFolder(Path)

    FCount = 0
    Set colFiles = objFolder.Files
        For Each objFile in colFiles
            strFile = objFile.Path
            dtmFileDate = objFile.DateLastModified
            If dtmOldestDate >= objFile.DateLastModified Then
               On Error Resume Next
               Wscript.Echo strFile
               objFSO.DeleteFile strFile, True
               If Not err <> 0 Then FCount = FCount + 1
               err.Clear
               On Error GoTo 0
            End If
        Next
        WScript.Echo colFiles.Count & " Dateien gesamt" 
        WScript.Echo FCount & " Datei(en) gelöscht"

    Set objFSO = Nothing
    Set objFolder = Nothing
    Set colFiles = Nothing

End Sub