Re: Excel und VBA - neues Arbeitsblatt nach Suchvorgang

Excel und VBA - neues Arbeitsblatt nach Suchvorgang (12 Beiträge, 199 Mal gelesen)

Du bist nicht angemeldet. [ Login/Registrieren ]

Hallo!

Ich schaffe es nicht, in Excel nach einer erfolgten "Input"-Abfrage, die Suchergebnisse in einem neuen Arbeitsblatt in der selben Datei zu erstellen, welches beim Schließen der Datei (ohne Abfrage) auch wieder gelöscht wird.

Also:

Input -> Dateien und Arbeitsblätter werden durchsucht -> neues Arbeitsblatt erstellen -> Fundstellen anzeigen -> Arbeitsblatt bei schließen löschen.

Geht das überhaupt?

Vielen Dank, SunnyHill.

Re: Excel und VBA - neues Arbeitsblatt nach Suchvorgang (dreamer30 am 12.05.2007, 23:15:59)

Re(2): Excel und VBA - neues Arbeitsblatt nach Suchvorgang (SunnyHill am 13.05.2007, 06:45:22)

Re(3): Excel und VBA - neues Arbeitsblatt nach Suchvorgang (dreamer30 am 13.05.2007, 07:14:57)

Sub x()
Dim wks As Worksheet
Dim strSearch As String, strFirst As String
Dim arrLocations()
Dim rngFound As Excel.Range
Dim intCounter

Do While Trim(strSearch) = ""
    strSearch = InputBox("Bitte Suchbegriff eingeben:")
Loop
strSearch = Trim(LCase(strSearch))
ReDim arrLocations(0 To 2, 0 To 0)
For Each wks In ActiveWorkbook.Worksheets
    Set rngFound = wks.Cells.Find(strSearch, LookIn:=xlValues)
    If Not rngFound Is Nothing Then
        strFirst = rngFound.Address
        Do
            intCounter = UBound(arrLocations, 2) + 1
            ReDim Preserve arrLocations(2, intCounter)
            arrLocations(0, intCounter) = wks.Name
            arrLocations(1, intCounter) = rngFound.Address
            arrLocations(2, intCounter) = rngFound.Text
            Set rngFound = wks.Cells.FindNext(rngFound)
        Loop While Not rngFound Is Nothing And rngFound.Address <> strFirst
    End If
Next wks
Worksheets.Add after:=Worksheets(Worksheets.Count)
Set wks = Worksheets(Worksheets.Count)
For intCounter = 1 To UBound(arrLocations, 2)
    wks.Cells(intCounter + 1, 1) = arrLocations(0, intCounter)
    wks.Cells(intCounter + 1, 2) = arrLocations(1, intCounter)
    wks.Cells(intCounter + 1, 3) = arrLocations(2, intCounter)
    wks.Hyperlinks.Add anchor:=Range("d" & intCounter + 1), Address:="", SubAddress:=arrLocations(0, intCounter) & "!" & arrLocations(1, intCounter), TextToDisplay:="...Goto"
Next
wks.Cells(1, 1) = "Tabelle"
wks.Cells(1, 2) = "Zelle"
wks.Cells(1, 3) = "Zellinhalt"
wks.Cells(1, 4) = "Link"
wks.name="Fundorte"
End Sub

bevor dem schließen löscht du dann das blatt:
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Worksheets("Fundorte").Delete
End Sub

mfg

Penguin

[ Dieser Beitrag wurde inzwischen editiert. Die aktuelle Version befindet sich hier. ]

Re: Excel und VBA - neues Arbeitsblatt nach Suchvorgang (Penguin am 13.05.2007, 14:15:15)

Re(2): Excel und VBA - neues Arbeitsblatt nach Suchvorgang (SunnyHill am 15.05.2007, 10:33:39)

Re(3): Excel und VBA - neues Arbeitsblatt nach Suchvorgang (SunnyHill am 18.05.2007, 13:21:29)

Re(4): Excel und VBA - neues Arbeitsblatt nach Suchvorgang (Penguin am 18.05.2007, 14:45:34)

Dieses Forum ist eine frei zugängliche Diskussionsplattform.
Der Betreiber übernimmt keine Verantwortung für den Inhalt der Beiträge und behält sich das Recht vor, Beiträge mit rechtswidrigem oder anstößigem Inhalt zu löschen.
Datenschutzerklärung