Public Sub runMe()
    'error handler definition
    On Error GoTo error_handler
    
    'define excel objects
    Dim wbWorkbook As Excel.Workbook
    Dim shSheet As Excel.Worksheet
    
    'set excel objects to currents
    Set wbWorkbook = ActiveWorkbook
    Set shSheet = ActiveSheet
    
    'last header row to include, start with 1 to <iLastHeaderRow>
    Dim iLastHeaderRow As Integer
    iLastHeaderRow = 2
    
    'get last filled in row number
    Dim lLastNonemptyRow As Long
    lLastNonemptyRow = shSheet.Cells.SpecialCells(xlCellTypeLastCell).Row
    
    'prep outlook objects for creating mail to send
    Dim aOutlook As Outlook.Application
    Set aOutlook = New Outlook.Application
    Dim mMailItem As Outlook.MailItem
    Set mMailItem = aOutlook.CreateItem(olMailItem)
    Call mMailItem.Display 'only works with displayed mail

    Dim objdoc As Object
    Dim objsel As Word.Selection

    Set objdoc = aOutlook.ActiveInspector.WordEditor
    Set objsel = objdoc.Windows(1).Selection
    
    'funny thing ... this doesn't work as expected - you always get also the lines in between the multiple nonconsecutive selects *grml*
    'shSheet.Range("1:" & iLastHeaderRow & "," & lLastNonemptyRow & ":" & lLastNonemptyRow).EntireRow.Select
    'shSheet.Range("1:" & iLastHeaderRow & "," & lLastNonemptyRow & ":" & lLastNonemptyRow).EntireRow.Copy
    
    'copy and paste header row(s)
    shSheet.Range("1:1, " & iLastHeaderRow & ":" & iLastHeaderRow).EntireRow.Copy
    Call objsel.Paste
    'copy and paste last row (outlook automatically joins it to one table)
    shSheet.Range(lLastNonemptyRow & ":" & lLastNonemptyRow).EntireRow.Copy
    Call objsel.Paste
    
    'explicit exit before running error handler
    Exit Sub
    
error_handler:
    Call MsgBox("Error: " & Err.Description, vbOKOnly + vbCritical, "Error " & Err.Number)

End Sub